Sending HTML Mail with Embedded Image in .NET
 
Published: 27 Jul 2007
Abstract
In this article Soyuj Kumar explains the classes which are useful in .NET for sending an HTML e-mail with an embedded image, attachments and much more.
by Soyuj Kumar Sahoo
Feedback
Average Rating: 
Views (Total / Last 10 Days): 520072/ 645

Introduction

After writing a couple of articles on CLR integration (in SQL Server 2005) technology this one is my first article purely based on .NET. I guess we all are habituated with emails. Sometimes we need to transfer more information in emails so we attach files, presentations, images, etc. and when we need it to be more attractive and colorful then we try our hand with HTML and insert images as necessary to make it more meaningful.

When we need to build this type of actions in our application, then we search for related   Components and Libraries to get support from. So, let us discuss .NET supported libraries to achieve this type of action in our application. In this article we will cover the System.Net.Mail Namespace of System.dll in .NET Framework 2.0 to build a mailing application.

About System.Net.Mail

This is the Namespace that contains the Classes used to send E-Mail using a SMTP (Simple Mail Transfer Protocol) client in .NET. There are four main Classes of our interest, namely MailMessage: represents the content of a mail, SmtpClient: responsible for delivering the Mails using a SMTP Server, Attachment: used in attaching files with mail content, and AlternateView: represents the MIME format to view a mail as an alternative.

This Namespace also contains some enumerations (enum) to specify different mail headers. Among them, "MailPriority" specifies the priority of a MailMessage, which is used later in our examples.

Objective

We are going to build a Service or Application that will Send Mail with some interesting features, like body content in html format, send to multiple recipients, send mail with attachment(s), to make it more meaningful send Html mail with Images Embedded in it, send HTML mail with embedded images and attachments, and mail with multipart bodies.

Steps in making a mail sending application

1.       A simple HTML mail

2.       A High priority mail with multipart bodies

3.       A mail with multiple recipients and attachments

4.       An HTML mail with embedded image

A simple HTML mail

Let us check a mail message created by System.Net.Mail.MailMessage to send a default mail.

Listing 1 – Sample for plain mail

Public Sub SendPlainMail()
 
  'create the mail message
  Dim mail As New MailMessage("from@fromdomain.com""to@todomain.com")
 
  'set the message content
  mail.Subject = "This is a plain text mail"
  mail.Body = "This is a sample body... for default Mail Clients.."
 
  'send the mail using SMTP Client
  Dim smtp As New SmtpClient("My Mail Server"'mail Server IP or NAME 
  smtp.Send(mail)
End Sub ' End SendPlainMail

Here, "mail" is the instance of MailMessage Class. There are four overloaded constructors available initializing different properties of MailMessage Class during making instance.

·         MailMessage (): Initializes an empty instance of the MailMessage class. 

·         MailMessage (from as MailAddress, to as MailAddress): Initializes a new instance of the   MailMessage class by using from and to as MailAddress class objects. 

·         MailMessage (from as String, to as String): Initializes a new instance of the MailMessage class by using from and to as String objects. 

·         MailMessage (from as String, to as String, subject as String, body as String): Initializes a new instance of the MailMessage class by using from, to, subject and body as String objects. 

Again, "smtp" is the instance of SmtpClient Class with Mail Server as parameter, which does the actual mail sending action. There are three available constructors of SmtpClient Class as:

·         SmtpClient (): Initializes a new instance of the SmtpClient class.

·         SmtpClient (host as String): Initializes a new instance of the SmtpClient class that sends email by using the specified SMTP server (host). 

·         SmtpClient (host as String, port as Int32): Initializes a new instance of the SmtpClient class that sends email by using the specified SMTP server and port. 

The MIME Source for above mail is:

Listing 2

'--------------------------------
x-recipient: <to@todomain.com>
Received: xxxxxxxxxxxx xxxxxxxxxxxxxxx xxxxxxxxxxxxxxxxxxxxxxxxx
(###### #, #, #, #); Fri, 22 Jun 07 18:53:37 +0530
mime-version: 1.0
from: from@fromdomain.com
to: to@todomain.com
date: 22 Jun 2007 18:53:37 +0530
subject: This is a plain text mail
content-type: text/plain; charset=us-ascii
content-transfer-encoding: quoted-printable
Message-Id: <f0706221908020DDAxxxxxx>
X-Antivirus: AVG for E-mail 7.5.472 [269.9.4/860]
This is a sample body... for default Mail Clients..
'--------------------------------

Here, the "content-type" field value is "text/plain," i.e. content-type: text/plain, which specifies that this Mail Client (Outlook or Eudora) is a plain mail only.

By default the mail message created by System.Net.Mail is a plain text, whose default value for   the Public Property MailMessage.IsBodyHtml is False. To format a message as Html we need to set this property MailMessage.IsBodyHtml property to True.

Listing 3 – Sample for HTML mail

Public Sub SendHtmlMail()
 
  'create the mail message
  Dim mail As New MailMessage("from@fromdomain.com""to@todomain.com")
 
   'set the message content
   mail.Subject = "This mail has Html Body.."
   mail.Body = "This is a sample body with html in it. <b>This is bold</b> <font
   color=#336699>This is blue</font>"
   mail.IsBodyHtml = True
   'send mail
   SendMail(mail)
End Sub ' End SendHtmlMail
 
Private Sub SendMail(ByVal mail As Mail.MailMessage)
  'send the message using SMTP client
  Dim smtp As New SmtpClient(_mailServer) 'mail Server IP or NAME
  smtp.Credentials = CredentialCache.DefaultNetworkCredentials
  smtp.Send(Mail)
End Sub ' End SendMail

The MIME Source for above mail is:

Listing 4 – Mime source of HTML mail

'--------------------------------
x-recipient: <to@todomain.com>
Received: xxxxxxxxxxxx xxxxxxxxxxxxxxx xxxxxxxxxxxxxxxxxxxxxxxxx
(###### #, #, #, #); Fri, 22 Jun 07 18:59:12 +0530
mime-version: 1.0
from: from@fromdomain.com
to: to@todomain.com
date: 22 Jun 2007 18:59:12 +0530
subject: This mail has Html Body..
content-type: text/html; charset=us-ascii
content-transfer-encoding: quoted-printable
Message-Id: <f0707041437531C0Axxxxxx>
X-Antivirus: AVG for E-mail 7.5.475 [269.9.4/860]
This is a sample body with html in it. <b>This is bold</b> 
<font color=3D#336699>This=is blue </font>
'--------------------------------

The "content-type" field value is "text/html" i.e. content-type: text/html, which specifies to the Mail Client (Outlook or Eudora) that this mail contains html content.

A High priority mail with multi part bodies

This example will demonstrate how to create a Multi-Part mime message. Multi-Part messages are messages that contain alternate body parts (at least 2 alternate body parts). Alternate body parts are used for displaying different content to different mail clients (like those who supports HTML). Because it is impossible to sniff or determine an end user's mail client application, i.e. whether it supports for Html or not, we need to create different alternate body parts. Then it is up to the mail client to display the richest body part that they can render. 

Again, the priority of a message is controlled by headers; in the System.Net.Mail namespace, the Priority of a message is actually exposed as a property of the MailMessage Class.

A priority can have the following values from MailPriority enum of System.Net.Mail namespace: High, Low, and Normal.

The following example creates the most common Multi-Part mime email, a Plain Text and an HTML Text email (2 alternate body parts) with High Priority.

Listing 5 – Sample for a multi-part mail

Public Sub MultiPartMailBody()
 
        'create the mail message
        Dim mail As New MailMessage("from@fromdomain.com""to@todomain.com")
 
        'set the message header
        mail.Subject = " This is a Multipart mail with hight Priority"
        mail.Priority = MailPriority.High
 
        'first we create the Plain Text part
        Dim plainView As AlternateView =
        AlternateView.CreateAlternateViewFromString("This is my plain 
        text content, viewable by those clients that don't support html"Nothing,
        "text/plain")
        mail.AlternateViews.Add(plainView)
 
        'then we create the Html part
        Dim htmlView As AlternateView =
        AlternateView.CreateAlternateViewFromString("<b>This is bold text, and
        viewable by those mail clients that support html</b>"Nothing,
        "text/html")
        mail.AlternateViews.Add(htmlView)
        'send mail
        SendMail(mail)
 
End Sub ' End MultiPartMailBody

"PlainView" and "htmlView" are the instances of AlternateView Class, which represents the format to view an email message. CreateAlternateViewFromString creates multi part mime body from the content specified in string.

The MIME Source for above mail is:

Listing 6

'--------------------------------
x-recipient: <to@todomain.com>
Received: xxxxxxxxxxxx xxxxxxxxxxxxxxx xxxxxxxxxxxxxxxxxxxxxxxxx
(###### #, #, #, #); Fri, 22 Jun 07 19:29:47 +0530
mime-version: 1.0
from: from@fromdomain.com
to: to@todomain.com
x-priority: 1
priority: urgent
importance: high
date: 22 Jun 2007 19:29:47 +0530
subject: This is a Multipart mail with high Priority
content-type: multipart/mixed; 
boundary=--boundary_0_d9be2464-dee8-4289-b8d3-f511389ec089
Message-Id: <f070704107052947xxxxxx>
X-Antivirus: AVG for E-mail 7.5.475 [269.9.4/860]
----boundary_0_d9be2464-dee8-4289-b8d3-f511389ec089
content-type: multipart/alternative; 
boundary=--boundary_1_f3c1985c-738d-4224-9e2f-8fd6d1e10548
----boundary_1_f3c1985c-738d-4224-9e2f-8fd6d1e10548
content-type: text/plain; charset=us-ascii
content-transfer-encoding: quoted-printable
This is my plain text content, 
viewable by those clients that don't support= html
----boundary_1_f3c1985c-738d-4224-9e2f-8fd6d1e10548
content-type: text/html; charset=us-ascii
content-transfer-encoding: quoted-printable
 
<b>This is bold text, and viewable by those mail clients that support html</b>
----boundary_1_f3c1985c-738d-4224-9e2f-8fd6d1e10548--
----boundary_0_d9be2464-dee8-4289-b8d3-f511389ec089--
'--------------------------------                     

The "boundary" of "content-type:" is the separator between two views of mail message.

A mail with multiple recipients and attachments

The "From" property of MailMessage is of MailAddress type. But the To, CC, and Bcc properties of MailMessage are MailAddress collections. So to add additional recipients, all we need to do is call .Add(...) on the respective properties.

Below is an example that demonstrates adding multiple To, CC, and Bcc addresses.

Listing 7 – Sample for attachment mail

Public Sub MultipleRecipients()
 
        'create the mail message
        Dim mail As New MailMessage()
 
        'set the addresses
        '-----------------------------------
        'to specify a friendly 'from' name, we use a different display name
        mail.From = New MailAddress("from@fromdomain.com""Display Name")
 
        'since the To, Cc, and Bcc properties are collections, to add multiple
         addreses, we simply call .Add(...) multple times
        mail.To.Add("to@todomain.com")
        mail.To.Add("to2@to2domain.com")
        mail.CC.Add("cc1@cc1domain.com")
        mail.CC.Add("cc2@cc2domain.com")
        mail.Bcc.Add("bcc1@bcc1domain.com")
        mail.Bcc.Add("bcc2@bcc2domain.com")
        '-----------------------------------
 
        'set the mail content
        mail.Subject = "This is an email with attachment"
        mail.Body = "This is the body content of the email."
 
        'set the attachment
        mail.Attachments.Clear()
        Dim attachment1 As New Attachment("c:\attachment\image1.jpg")
        mail.Attachments.Add(attachment1)
        mail.Attachments.Add(New Attachment("c:\attachment\text1.txt"))
 
        'send mail
        SendMail(mail)
 
End Sub ' End MultipleRecipients

Here, "attachment1" is the instance of Attachment Class of System.Net.Mail namespace, which is a property of MailMessage to get the attachment collection used to store data attached.

One part of MIME Source for above mail is:

Listing 8 – Mime source of a mail with attachment

'--------------------------------
subject: This is an email with attachment
content-type: multipart/mixed; 
boundary=--boundary_0_967ab941-2985-4b6a-8a69-adfb17fb1951
Message-Id: <f0707041632541xxxxxxxxx>
X-Antivirus: AVG for E-mail 7.5.476 [269.9.14/885]
----boundary_0_967ab941-2985-4b6a-8a69-adfb17fb1951
content-type: text/plain; charset=us-ascii
content-transfer-encoding: quoted-printable
This is the body content of the email.
----boundary_0_967ab941-2985-4b6a-8a69-adfb17fb1951
content-type: application/octet-stream; name=image1.jpg
content-transfer-encoding: base64
/9j/4AAQSkZJRgABAQEAYABgAAD/4QAWRXhpZgAASUkqAAgAAAAAAAAAAAD/2wBDAAEBAQEB
AQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEBAQEB
EBAQEBAQE... .....  ......  ....   ..  ..  .
..... ....   .........  ...  ...  .. .. ..
----boundary_0_967ab941-2985-4b6a-8a69-adfb17fb1951
content-type: application/octet-stream; name=text1.txt
content-transfer-encoding: base64
SGkgVGhpcyBmaWxlIGlzIGF0dGFjaGVkIGZpbGUuDQoNCkNhbiB1IHJlYWQgdGhpcyBmaWxl
Lg0KD.................
----boundary_0_967ab941-2985-4b6a-8a69-adfb17fb1951--
'--------------------------------
An Html mail with embedded image

Embedding images is something that is new with System.Net.Mail in .NET Framework 2.0. To embed an image we will need to:

·         Create an AlternateView object for the Image. The AlternateView will actually contain the binary data of the Image. This binary data is encoded as part of the email and sent along as part of the MailMessage.

·         Set the ContentId property of AlternateView Class to a unique value.

·         Create a HTML AlternateView.

·         Inside that HTML text, we need to use the standard <img> tag.

·         For the "src" value, we need to point it at the Content-Id of the AlternateView image. This is done by using the syntax <img src="cid:ContentId value">. The "src=cid:" part is required for the email client to recognize the <img> tag as an embedded image, while the "ContentId value" part is the actual Content-Id of the AlternateView image. 

That is all there is to create an embedded image view. Below is a short but complete example that demonstrates creating an embedded image message.

Listing 9 – Sample of an Html mail with embedded image

Public Sub EmbeddedImages()
 
        'create the mail message
        Dim mail As New MailMessage()
 
        'set the addresses
        mail.From = New MailAddress("from@fromdomain.com", " Display Name")
        mail.To.Add("to@todomain.com")
       
        'set the content
        mail.Subject = "This is an embedded image mail"
 
        'first we create the Plain Text part
        Dim palinBody As String = "This is my plain text content, viewable by
        those clients that don't support html"
        Dim plainView As AlternateView =
        AlternateView.CreateAlternateViewFromString(palinBody, Nothing,
        "text/plain")
        'then we create the Html part
        'to embed images, we need to use the prefix 'cid' in the img src value
        Dim htmlBody As String = "<b>This is the embedded image 
        file.</b><DIV>&nbsp;</DIV>"
        htmlBody += "<img alt="""" hspace=0 src=""cid:uniqueId"" align=baseline 
        border=0 >"
        htmlBody += "<DIV>&nbsp;</DIV><b>This is the end of Mail...</b>"
        Dim htmlView As AlternateView =
         AlternateView.CreateAlternateViewFromString(htmlBody, Nothing,
         "text/html")
 
        'create the AlternateView for embedded image
        Dim imageView As New AlternateView("c:\attachment\image1.jpg",
        MediaTypeNames.Image.Jpeg)
        imageView.ContentId = "uniqueId"
        imageView.TransferEncoding = TransferEncoding.Base64
 
        'add the views
        mail.AlternateViews.Add(plainView)
        mail.AlternateViews.Add(htmlView)
        mail.AlternateViews.Add(imageView)
 
        'send mail
        SendMail(mail)
 
End Sub ' End EmbedImages

"ImageView" is the instance of AlternateView created using the constructor which takes two parameters as: fileName (with path of image) as String, and mediaType as String. Here we use the public string type constant "Jpeg" of MediaTypeNames.Image Class, which is actually “image/jpeg."

Again, the "TransferEncoding" property of "imageView" (AlternateView Class) is set to "Base64."

Sample source code

Let us check the steps for creating a sample Mail Sending application in Visual Basic 2005. We have to follow the steps below.

·         Open Visual Studio 2005 and create a new console application project. Named it "MailSendingApp."

·         Copy and paste the following codes in that module and named it "SampleModule.vb."

Listing 10 – Sample source code of Mail sending application

Imports System.Net
Imports System.Net.Mail
Imports System.Net.Mime
Module SampleModule
 
    Private _mailServer As String = String.Empty
 
    ''' <summary>
    ''' The starting function of console application.
    ''' </summary>
    ''' <remarks>Need to set the mail server details from console</remarks>
    Sub Main()
 
        Console.WriteLine("Welcome to Soyuj's Mail send application..")
        Console.WriteLine("Enter your Mail Server :: ")
        _mailServer = Console.ReadLine()
 
        EmbeddedImages()
 
        Console.WriteLine(ControlChars.CrLf & "Completed...")
        Console.ReadLine()
 
    End Sub
 
    ''' <summary>
    ''' Sends mail using SMTP client
    ''' </summary>
    ''' <param name="mail">The SMTP server (MailServer) as String</param>
    ''' <remarks>It can use the IP of Server also</remarks>
    Private Sub SendMail(ByVal mail As Mail.MailMessage)
 
        'send the message using SMTP client
        Dim smtp As New SmtpClient(_mailServer) 'mail Server IP or NAME 
        smtp.Credentials = CredentialCache.DefaultNetworkCredentials
        smtp.Send(Mail)
 
    End Sub ' End SendMail
 
    ''' <summary>
    ''' Sets the content of MailMessage for default(plain text)
    ''' </summary>
    ''' <remarks>This is accessible by all Mail Clients</remarks>
    Public Sub SendPlainMail()
 
        'create the mail message
        Dim mail As New MailMessage("from@fromdomain.com""to@todomain.com")
 
        'set the message content
        mail.Subject = "This is a plain text mail"
        mail.Body = "This is a sample body... for default Mail Clients.."
 
        'send the mail using SMTP Client
        Dim smtp As New SmtpClient("My Mail Server") 'mail Server IP or NAME 
        smtp.Send(mail)
 
    End Sub ' End SendPlainMail
 
    ''' <summary>
    ''' Sets the content of MailMessage for a Html body only
    ''' </summary>
    ''' <remarks>The Html body is created using standard html tags..</remarks>
    Public Sub SendHtmlMail()
 
        'create the mail message
        Dim mail As New MailMessage("from@fromdomain.com""to@todomain.com")
 
        'set the message content
        mail.Subject = "This mail has Html Body.."
        mail.Body = "body with html<b>bold</b> <font color=#336699>blue</font>"
        mail.IsBodyHtml = True
 
        'send mail
        SendMail(mail)
 
    End Sub ' End SendHtmlMail
 
    ''' <summary>
    ''' Sets the MailMessage content with multiple body parts
    ''' (e.g a Html part and a PlainText part..)
    ''' </summary>
    ''' <remarks>Plain body is for Mail Clients, 
    ''' those don't support Html</remarks>
    Public Sub MultiPartMailBody()
 
        'create the mail message
        Dim mail As New MailMessage("from@fromdomain.com", "to@todomain.com")
 
        'set the message header
        mail.Subject = " This is a Multipart mail with hight Priority"
        mail.Priority = MailPriority.High
 
        'first we create the Plain Text part
        Dim plainView As AlternateView =
            AlternateView.CreateAlternateViewFromString(
            "Plain text content, viewable by clients that don't support html",
            Nothing"text/plain")
        mail.AlternateViews.Add(plainView)
 
        'then we create the Html part
        Dim htmlView As AlternateView = 
            AlternateView.CreateAlternateViewFromString(
            "<b>bold text, viewable by mail clients that support html</b>",
            Nothing"text/html")
        mail.AlternateViews.Add(htmlView)
 
        'send mail
        SendMail(mail)
 
    End Sub ' End MultiPartMailBody
 
    ''' <summary>
    ''' Set the MailMessage instance for multiple recipients with attachment
    ''' </summary>
    ''' <remarks>From address can be customized to show a Display Name</remarks>
    Public Sub MultipleRecipients()
 
        'create the mail message
        Dim mail As New MailMessage()
 
        'set the addresses
        '-----------------------------------
        'to specify a friendly 'from' name, we use a different display name
        mail.From = New MailAddress("from@fromdomain.com""Display Name")
 
        'since the To, Cc, and Bcc properties are collections, to add multiple
        'addreses, we simply call .Add(...) multple times
        mail.To.Add("to@todomain.com")
        mail.To.Add("to2@to2domain.com")
        mail.CC.Add("cc1@cc1domain.com")
        mail.CC.Add("cc2@cc2domain.com")
        mail.Bcc.Add("bcc1@bcc1domain.com")
        mail.Bcc.Add("bcc2@bcc2domain.com")
        '-----------------------------------
 
        'set the mail content
        mail.Subject = "This is an email with attachment"
        mail.Body = "This is the body content of the email."
 
        'set the attachment
        mail.Attachments.Clear()
        Dim attachment1 As New Attachment("c:\attachment\image1.jpg")
        mail.Attachments.Add(attachment1)
        mail.Attachments.Add(New Attachment("c:\attachment\text1.txt"))
 
        'send mail
        SendMail(mail)
 
    End Sub ' End MultipleRecipients
 
    ''' <summary>
    ''' Embeds an image in a Html body of MailMessage
    ''' </summary>
    ''' <remarks>The standard image tag must be there in html body with 'cid' 
    ''' in src value</remarks>
    Public Sub EmbeddedImages()
 
        'create the mail message
        Dim mail As New MailMessage()
 
        'set the addresses
        mail.From = New MailAddress("from@fromdomain.com"" Display Name")
        mail.To.Add("to@todomain.com")
       
        'set the content
        mail.Subject = "This is an embedded image mail"
 
        'first we create the Plain Text part
        Dim palinBody As String = 
          "Plain text content, viewable by those clients that don't support html"
        Dim plainView As AlternateView =
            AlternateView.CreateAlternateViewFromString
            (palinBody, Nothing, "text/plain")
        'then we create the Html part
        'to embed images, we need to use the prefix 'cid' in the img src value
        Dim htmlBody As String = "<b>Embedded image file.</b><DIV>&nbsp;</DIV>"
        htmlBody += 
        "<img alt="""" hspace=0 src=""cid:uniqueId"" align=baseline border=0 >"
        htmlBody += "<DIV>&nbsp;</DIV><b>This is the end of Mail...</b>"
        Dim htmlView As AlternateView =
             AlternateView.CreateAlternateViewFromString
            (htmlBody, Nothing, "text/html")
 
 
        'create the AlternateView for embedded image
        Dim imageView As New AlternateView("c:\attachment\image1.jpg",
            MediaTypeNames.Image.Jpeg)
        imageView.ContentId = "uniqueId"
        imageView.TransferEncoding = TransferEncoding.Base64
 
 
        'add the views
        mail.AlternateViews.Add(plainView)
        mail.AlternateViews.Add(htmlView)
        mail.AlternateViews.Add(imageView)
 
        'send mail
        SendMail(mail)
 
    End Sub ' End EmbedImages
 
End Module ' End SampleModule
 

·         Change the To, From, Cc, Bcc, etc. address to your type (but must be valid).

·          Press F5 to start debugging and follow the instructions from the console.

Figure 1- (sample console)

·         Enter your Mail Server address.

·         Check the output mail in your Mail Box. My sample output is:

Figure 2 - (Output sample mail)

NOTE: Before using the above code, be sure to set your email addresses in the required place with Mail Server (SMTP).

Conclusion

I believe you are smart enough to change these sample codes for your different uses, such as for Windows Application, Web Application, a Class Library, etc. I have not implemented any exception handling concept for better debugging, this is a task for you. I hope you had a good session with this article.

By Soyuj Kumar Sahoo

MindFire solutions



User Comments

Title: Attachment needed.   
Name: Chieko
Date: 2012-11-27 10:39:48 AM
Comment:
I was so happy I could use this piece of code to add images to emails. The image did not show up in all of the emails until I added an attachment to the mail object.
' create email attachement.
Dim attach As New Net.Mail.Attachment(imagepath)
Title: www.hairsshop.co.uk   
Name: weimin fu
Date: 2012-06-28 8:50:04 PM
Comment:
The idea behind upgrading the world’s major tourist locales was to help travelers

better navigate otherwise unfamiliar areas, and probably to show off a little.

Structures like the Piazza del Duomo, that were once boxy buildings with some

dimension, now take on more dynamic shapes.
Title: Herve Leger Dress   
Name: Herve Leger Dress
Date: 2012-05-22 10:11:14 PM
Comment:
It’s fun.Very worth to read.
Title: mail id send information   
Name: karthi
Date: 2012-05-16 3:04:31 AM
Comment:
ss
Title: www.cheapguccibeltoutlet.com   
Name: www.cheapguccibeltoutlet.com
Date: 2012-04-27 11:20:38 PM
Comment:
xyzboy6666 Designer sunglasses are also http://www.cheapguccibeltoutlet.com available which are designed by designers according to the customer's requirement.http://www.cheapsunglassesexport.com Every person likes to wear Designer sunglasses which enhance their personality. http://www.louisvuittonbeltscheap.comAs we know great personalities of world like to wear glasses according to their dress.
Title: work well   
Name: canada goose parka
Date: 2011-11-19 6:03:20 AM
Comment:
just pass here,who interest winter jackets,can click my name,free ship and at least 70% discount,no interest ignore this messege.thanks
Title: Forwarding problem   
Name: Abhinay
Date: 2011-04-13 1:20:30 AM
Comment:
I am facing problem while forwarding the mail.I have created mail as mention in article.It sends mail perfectly but when I forward that mail if does not contain the embedded image.
Title: it didnot work   
Name: CC
Date: 2011-04-04 3:48:33 PM
Comment:
Hello

your code didnot working for me( IE8) et outlook 2007
i see the X
Title: Browser support   
Name: Sh
Date: 2011-04-02 8:29:27 AM
Comment:
Hi

Does all client browser support embedded images in email.
Does the embedded image be displayed in gmail or outlook??
Title: Email Problem   
Name: Mohit Chauhan
Date: 2010-12-14 4:36:30 AM
Comment:
actually my question is:
i want mail full capture page.when i send it then the page capture the pop up page.i am really confuse. how to capture previous page.

StringBuilder sb = new StringBuilder();
StringWriter sw = new StringWriter(sb);
HtmlTextWriter htmlTw = new HtmlTextWriter(sw);
base.Render(htmlTw);


plz reply any one
mohit chauhan
mohit@purplehazeonline.com
mohit.chauhan8@gmail.com
Title: Well, you mention here things that really made me think.   
Name: ugg boots cheap
Date: 2010-11-26 10:19:13 AM
Comment:
Well, you mention here things that really made me think.
Title: Sending HTML Mail with Embedded Image in .NET   
Name: Ramkumar
Date: 2010-11-18 10:30:37 AM
Comment:
Hi Soyuj,
I tried with the same code and replaced the image location, From and To address values. But i am getting 'X' mark in place of image. But when i replace the HTML src with the original image location, the image is displayed in the mail. Kindly help me in solving this. I am using MS Outlook
Title: hi Anowar   
Name: prasath
Date: 2010-09-06 4:44:12 AM
Comment:
how to embed image with background of TD tag ,
could you please send piece of code..

prasath.r@3rd-wave.com
Title: Hotmail Problem   
Name: Anowar
Date: 2010-08-24 4:01:26 AM
Comment:
I have used embedded image as background image of a TD tag and its working(showing) fine with yahoo email. But in hotmail it is not showing(background image).

Can you please suggest me what to do??
Title: hello sir   
Name: anup
Date: 2010-07-22 5:39:41 AM
Comment:
thanks u for gudding me
Title: Thanks!   
Name: Fredrik
Date: 2010-07-19 4:37:24 PM
Comment:
I was going crazy, not finding anything about how to embed a picture in my email. This post made my day. Thank you!
Title: email tracking   
Name: sagar
Date: 2010-06-04 5:39:09 AM
Comment:
nice coding
Title: Example fail   
Name: David Pineda
Date: 2010-05-20 12:34:43 PM
Comment:
Hi, unfortunely this sample fail, be cause the image is not present in the mail, just i can see square with 'X'.
Title: dwfgdsfg   
Name: dfgdsdfg
Date: 2010-04-14 3:28:22 PM
Comment:
Cool
Title: I love the palin joke   
Name: mark
Date: 2010-02-22 1:23:17 PM
Comment:
I assume you meant that as a joke..

Dim palinBody As String = "This is my plain text content, viewable by those clients that don't support html"
Title: ugg boots   
Name: ugg boots
Date: 2010-02-06 2:23:53 AM
Comment:
I recently came across your blog and have been reading along.[url=http://www.sellcheapuggs.com]ugg[/url] I thought I would leave my first comment. [url=http://www.sellcheapuggs.com]ugg boots[/url] I don’t know what to say except that I have enjoyed reading.[url=http://www.sellcheapuggs.com]cheap ugg boots[/url] Nice blog.
Title: Different Way   
Name: Phil
Date: 2010-01-28 2:30:36 PM
Comment:
\
Title: ugg boots   
Name: ugg boots
Date: 2009-12-24 7:48:59 PM
Comment:
Thanks for the GREAT post. After fighting a bit with the image displaying in Hotmail, I came up with this code which seems to make it work
Title: Hotmail   
Name: Graham
Date: 2009-12-11 7:30:00 AM
Comment:
Hi Pieter, could you post your entire code for image attachments for Hotmail. What about for multiple images? Would I need to create multiple image views?
Title: OWA, Hotmail, Yahoo and Googlemail   
Name: Pieter
Date: 2009-10-07 4:57:21 PM
Comment:
\
Title: OWA   
Name: Pieter
Date: 2009-10-07 3:55:53 PM
Comment:
My last comment did not include this line which breaks it for Exchange Web Access:
data.Name = "image2.jpg";

Sorry...
Title: Hotmail   
Name: Pieter
Date: 2009-10-07 3:34:16 PM
Comment:
Hi
Thanks for the GREAT post. After fighting a bit with the image displaying in Hotmail, I came up with this code which seems to make it work:
Attachment data = new Attachment(imageView.ContentStream, MediaTypeNames.Image.Gif);
data.ContentDisposition.Inline = true;
data.ContentId = "uniqueId";
data.TransferEncoding = TransferEncoding.Base64;
message.Attachments.Add(data);

Just use that instead of the message.AlternateViews.Add(imageView);

Hopefully this will help someone.
Title: So cool, thanks.   
Name: Richard
Date: 2009-07-02 2:56:31 PM
Comment:
In stead of sending the embedded image email, How can we save it into the .eml template file?
Title: Error by using this codes   
Name: Nelson
Date: 2009-05-28 10:53:20 PM
Comment:
dear friends
this is very useful for me, when i put this codes to my code it was getting error like follows

Type 'MailMessage' is not defined
i think i have done some mistake, please help me to solve this problem

Thanks in ADvanced
Dim mail As New MailMessage
Title: embedded Email   
Name: Suresh
Date: 2009-05-18 7:03:04 AM
Comment:
Very Good Code. Thanks
Title: Works well, both google and yahoo   
Name: Sangam Uprety
Date: 2009-03-27 8:48:30 AM
Comment:
Hi Soyuj!
Thanks for the descriptive tutorial.
This has worked for me smart!
I could get the images embedded in my mail which displayed well in google mail (gmail) and yahoo mail. But I could not test it now with hotmail.

The only problem is that I cannot get it displayed in the mail readers that use plain view. The result is awsome- the image link is being displayed, with cid:uniqueid as src of the image. Looks ugly.

With best regards,
Sangam Uprety
http://dotnetspidor.blogspot.com
Title: This code is faulty   
Name: Vlax
Date: 2008-11-29 11:28:08 PM
Comment:
Look for another example in the net.
The attached image doesn't come right, you need to use "relatedfiles" or something like that instead of creating a additional AlternateView
Title: Need urgent help   
Name: Gandhi Basnet
Date: 2008-11-22 11:16:37 PM
Comment:
The code is working good now,
but the problem is when ever i am sending mail
the word "spam" is getting added to the subject
like if i send test it is like spam test in the subject line when i receive the mail

please help me out

thanks
Title: Works on Outlook Express but not for Outlook 2007   
Name: Gandhi Basnet
Date: 2008-11-20 3:58:33 AM
Comment:
The embedded image is displayed in Outlook Express but not in Outlook 2007.
Please help me out.
Title: Thanks and a great job   
Name: Chris
Date: 2008-11-10 2:30:00 PM
Comment:
I work in C#, and know little of VB.NET, but your code is just great and understandable still.

Congratulations!
Title: need help urgent   
Name: Geani
Date: 2008-10-27 10:18:25 AM
Comment:
I used same code. The only difference is the location of the image to be loaded. But, Image doesn't display properly.
It shows just an icon at the place of image. could u help me
Title: need help urgent   
Name: Rahul
Date: 2008-10-09 7:29:35 AM
Comment:
It was a nice article.
But Image doesn't display properly.
it shows just a icon at the place of image
could u help me

Thanks
Title: need help -urgent   
Name: sunil
Date: 2008-08-20 12:25:16 AM
Comment:
i tried ur code its working good
but the problem is when ever i am sending mail
the word "spam" is getting added to the subject
like if i send test it is like spam test in the subject line when i receive the mail

please help me out

thanks
Title: great job   
Name: bunny
Date: 2008-08-18 10:16:20 PM
Comment:
great work thanq very much for the post
i was working with web.mail some i got some issue with that
and ur code its really wow
thaks once again
Title: Gr8 buddy   
Name: Ankit Maini
Date: 2008-06-27 6:35:42 AM
Comment:
Thanx buddy nice article for me.
Title: For Local Host   
Name: Prince Mathew
Date: 2008-02-19 11:23:33 PM
Comment:
Thanks a lot... it saved much time...
Found some settings is needed to send thru localhost as server. Link provided will help

http://codebetter.com/blogs/peter.van.ooijen/archive/2006/04/05/Using-localhost-as-mailserver-_2800_5.7.1-Unable-to-relay-for-xxx_2900_.aspx
Title: View message before sending   
Name: Jerre
Date: 2008-01-30 9:23:19 AM
Comment:
I there a way to view the message in outlook 2003 first before sending it?
Title: Thank You Very Much...   
Name: Slawek
Date: 2007-12-15 7:05:52 PM
Comment:
Your article helped me very, very much and saved me much time. I think, you could add an examle how to authenticate on smtp server using login/password (single line at the end of this comment), and article will be truly complete
Slawek

smtp.Credentials = new System.Net.NetworkCredential(login,password)
Title: Imran   
Name: Imran Ali
Date: 2007-11-06 10:56:14 AM
Comment:
Hello ... Thank you ,,, It is very helpful
Title: ThankxxX   
Name: Mohammed. Akhtar
Date: 2007-08-29 6:18:45 AM
Comment:
It was very useful.
Title: Thanx To You   
Name: Sai
Date: 2007-08-10 1:28:03 AM
Comment:
Hello Sir,

I got good idea from this article but i expecting to know how can i read mails came to me in my gmail account in my asp.net application using POP3 Access.
Title: Pankaj   
Name: Pankaj Baviskar
Date: 2007-08-07 9:18:21 AM
Comment:
\
\
Title: Very good work   
Name: Jose
Date: 2007-08-07 2:36:54 AM
Comment:
Thank you Soyuj for this very good work. Each step is very well explained. Good job!
Title: Thanks!   
Name: Oscar
Date: 2007-08-06 11:53:30 AM
Comment:
Thanks a lot Soyuj! i'll try it that way
Title: Hotmail issue..   
Name: Soyuj Kumar
Date: 2007-08-06 3:41:14 AM
Comment:
Hello Oscar,

I have already checked with LinkedResource class and it is working fine for Hotmail.... try this..

Thanks.

Soyuj
Title: I am trying   
Name: Soyuj Kumar
Date: 2007-08-06 3:20:24 AM
Comment:
Hi...

Thanks for this nice questions!!! I have tried with Yahoo, Gmail, Hotmail... but got failed in Hotmail to see the image.. Yahoo and Gmail supports...

Please check the message source in all the experimental cases.. hello Kevin check the Outlook's source if the image source is there then we need to do some R&D..

BTW, another possible way is to try this action using "LinkedResource" which will take the path of the image.. and then (AlternateView)htmlView.add(LinkedResource) ....

So, please try with this...

Thanks,
Soyuj
Title: Thank You!   
Name: amin behzadi
Date: 2007-08-04 3:57:15 AM
Comment:
Excelent...! Very nice and clear to understandig.
thank you!
Title: Question   
Name: Oscar
Date: 2007-08-03 11:20:02 AM
Comment:
Excelent code Soyuj!! i have a question..the example works fine if i see the mail message in gmail(i see the text and the image), but in msnHotmail(i see the text and a gray box instead of the image) in mozilla i only see the image..
What could be the problem? is there any special setup that we need to see this mail correclty??
Thanks a lot!!!
Title: Thank, another question ask   
Name: Kevin
Date: 2007-08-03 2:43:25 AM
Comment:
your code got worked in outlook express, failed in outlook.

in outlook, i just saw a red cross instead of the pic. Do you know why or have you tested it like that?

any ideas please feel free to contact me via kevins@verdant.com.au. thanks again.

Cheers,
Kevin
Title: Thanks   
Name: Soyuj Kumar
Date: 2007-08-02 8:54:49 AM
Comment:
Thanks !!! for these nice comments...
Title: Enjoyed your article   
Name: Patricia
Date: 2007-08-01 10:33:58 PM
Comment:
Your writing style makes it so clear to understand. Thank you and looking forward to more of your articles.
Title: Nice work   
Name: John
Date: 2007-07-27 3:29:23 AM
Comment:
Nice work man.. Keep it up !!!

Product Spotlight
Product Spotlight 





Community Advice: ASP | SQL | XML | Regular Expressions | Windows


©Copyright 1998-2019 ASPAlliance.com  |  Page Processed at 2019-09-21 5:41:46 PM  AspAlliance Recent Articles RSS Feed
About ASPAlliance | Newsgroups | Advertise | Authors | Email Lists | Feedback | Link To Us | Privacy | Search